ExcelとVBAでプロジェクトフォルダを一瞬で初期化するマクロ【環境変数対応】

Sub InitializeProjectFolder()
    Dim folderName As String
    Dim baseFolderPath As String
    Dim projectFolderPath As String
    Dim srcFolderPath As String
    Dim archiveFolderPath As String
    Dim readmePath As String
    Dim fso As Object
    Dim wshShell As Object
    
    ' アクティブセルからフォルダ名取得
    folderName = Trim(ActiveCell.Value)
    
    If folderName = "" Then
        MsgBox "アクティブセルが空です。フォルダ名を入力してください。"
        Exit Sub
    End If
    
    ' 環境変数 %PROJECTS% を取得
    Set wshShell = CreateObject("WScript.Shell")
    baseFolderPath = wshShell.ExpandEnvironmentStrings("%PROJECTS%")
    
    If baseFolderPath = "%PROJECTS%" Then
        MsgBox "環境変数 PROJECTS が設定されていません。"
        Exit Sub
    End If
    
    ' フォルダパス定義
    projectFolderPath = baseFolderPath & "\work\" & folderName
    srcFolderPath = projectFolderPath & "\src"
    archiveFolderPath = projectFolderPath & "\archive"
    readmePath = projectFolderPath & "\README.md"
    
    ' FSOオブジェクト
    Set fso = CreateObject("Scripting.FileSystemObject")
    
    ' プロジェクトフォルダ作成
    If Not fso.FolderExists(projectFolderPath) Then
        fso.CreateFolder projectFolderPath
    End If
    
    ' srcフォルダ作成
    If Not fso.FolderExists(srcFolderPath) Then
        fso.CreateFolder srcFolderPath
    End If
    
    ' archiveフォルダ作成
    If Not fso.FolderExists(archiveFolderPath) Then
        fso.CreateFolder archiveFolderPath
    End If
    
    ' README.md作成
    If Not fso.FileExists(readmePath) Then
        Dim readmeFile As Object
        Set readmeFile = fso.CreateTextFile(readmePath, True)
        readmeFile.WriteLine "# " & folderName
        readmeFile.Close
    End If
    
    ' フォルダをエクスプローラで開く
    Shell "explorer.exe """ & projectFolderPath & """", vbNormalFocus
    
    MsgBox "プロジェクトフォルダを初期化しました：" & projectFolderPath
End Sub

%PROJECTS%/work/プロジェクト名/
├── src/
├── archive/
└── README.md